next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: latticePoints(ToricDivisor)

latticePoints(ToricDivisor) -- computes the lattice points in the associated polytope

Synopsis

Description

On a complete normal toric variety, the polyhedron associated to a Cartier divisor is a lattice polytope. Given a torus-invariant Cartier divisor on a normal toric variety, this method returns an integer matrix whose columns correspond to the lattices points contained in the associated polytope. For a non-effective Cartier divisor, this method returns null.

On the projective plane, the associate polytope is either empty, a point, or a triangle.

i1 : PP2 = projectiveSpace 2;
i2 : vertices (-PP2_0)
i3 : null === vertices (- PP2_0)

o3 = true
i4 : latticePoints (0*PP2_0)

o4 = 0

              2        1
o4 : Matrix ZZ  <--- ZZ
i5 : isAmple PP2_0

o5 = true
i6 : V1 = latticePoints (PP2_0)

o6 = | 0 0 1 |
     | 0 1 0 |

              2        3
o6 : Matrix ZZ  <--- ZZ
i7 : X1 = normalToricVariety V1;
i8 : set rays X1 === set rays PP2

o8 = true
i9 : max X1 === max PP2

o9 = true
i10 : isAmple (2*PP2_0)

o10 = true
i11 : V2 = latticePoints (2*PP2_0)

o11 = | 0 0 0 1 1 2 |
      | 0 1 2 0 1 0 |

               2        6
o11 : Matrix ZZ  <--- ZZ
i12 : X2 = normalToricVariety(V2, MinimalGenerators => true);
i13 : rays X2 === rays X1

o13 = true
i14 : max X2 === max X1    

o14 = true
In this singular example, we see that all the lattice points in the polytope arising from a divisor 2D do not come from the lattice points in the polytope arising from D.
i15 : Y = normalToricVariety matrix {{0,1,0,0,1},{0,0,1,0,1},{0,0,0,1,1},{0,0,0,0,3}};
i16 : D = 3*Y_0;

o16 : ToricDivisor on Y
i17 : latticePoints D

o17 = | 0 0 0 1 1 |
      | 0 0 1 0 1 |
      | 0 1 0 0 1 |
      | 0 0 0 0 3 |

               4        5
o17 : Matrix ZZ  <--- ZZ
i18 : latticePoints (2*D)

o18 = | 0 0 0 0 0 0 1 1 1 1 1 1 1 2 2 2 |
      | 0 0 0 1 1 2 0 0 1 1 1 1 2 0 1 2 |
      | 0 1 2 0 1 0 0 1 0 1 1 2 1 0 1 2 |
      | 0 0 0 0 0 0 0 0 0 2 3 3 3 0 3 6 |

               4        16
o18 : Matrix ZZ  <--- ZZ

See also